'From Squeak2.9alpha of 13 June 2000 [latest update: #2518] on 4 January 2001 at 11:18:41 am'!
"Change Set:		BlobMPEGMorphJMM
Date:			19 December 2000
Author:			johnmci@smalltalkconsulting.com

Why have a boring MPEG video viewer when you can do exciting things with Morphic. So that that end here is an example of things you can do by using existing features, like the Blob"!

Smalltalk renameClassNamed: #BlobMPEGViewer as: #BlobMPEGMorph!
BlobMorph subclass: #BlobMPEGMorph
	instanceVariableNames: 'mpegLogic form movieDrawArea primary quadNumber '
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Morphic-Demo'!

!BlobMPEGMorph commentStamp: 'JMM 1/4/2001 11:13' prior: 0!
Ok this is a little follow on to David's BlobMorph. Why not embedded a movie in the blob I thought. So with a few minutes of help from John Maloney we have something very interesting.

Enjoy John M McIntosh <johnmci@smalltalkconsulting.com> Dec 2000. (Christmas early)!

!BlobMPEGMorph methodsFor: 'access' stamp: 'JMM 10/19/2000 16:02'!
form
	^form! !

!BlobMPEGMorph methodsFor: 'access' stamp: 'JMM 10/19/2000 16:02'!
form: aForm
	form _ aForm! !

!BlobMPEGMorph methodsFor: 'access' stamp: 'JMM 12/19/2000 16:01'!
movieDrawArea
	^movieDrawArea! !

!BlobMPEGMorph methodsFor: 'access' stamp: 'JMM 10/19/2000 15:54'!
mpegLogic
	^mpegLogic! !

!BlobMPEGMorph methodsFor: 'access' stamp: 'JMM 10/19/2000 15:54'!
mpegLogic: aValue
	mpegLogic _ aValue! !

!BlobMPEGMorph methodsFor: 'access' stamp: 'JMM 12/19/2000 15:45'!
primary
	^primary! !

!BlobMPEGMorph methodsFor: 'access' stamp: 'JMM 12/19/2000 21:52'!
quadNumber
	^quadNumber! !

!BlobMPEGMorph methodsFor: 'access' stamp: 'JMM 1/4/2001 10:53'!
quadNumber: aNumber
	quadNumber _ aNumber! !

!BlobMPEGMorph methodsFor: 'access' stamp: 'JMM 10/19/2000 15:59'!
stream
	^0! !

!BlobMPEGMorph methodsFor: 'initialization' stamp: 'JMM 1/4/2001 11:06'!
initialize: primaryFlag mpegPlayer: aMpegPlayerOrFileName 
	| rect sizeToOverLapBoundary |

	primary _ primaryFlag.
	rect _ self bounds.
	sizeToOverLapBoundary _ 3.0.
	primary 
		ifTrue: [form _ Form extent: 
					((sizeToOverLapBoundary * rect width) @ (sizeToOverLapBoundary * rect height)) truncated depth: 32.
				movieDrawArea _ SketchMorph withForm: form.
				mpegLogic _ MPEGPlayer playFile: aMpegPlayerOrFileName onMorph: movieDrawArea]
		ifFalse: [form _ aMpegPlayerOrFileName form.
				movieDrawArea _ aMpegPlayerOrFileName movieDrawArea.
				mpegLogic _ aMpegPlayerOrFileName mpegLogic]
! !

!BlobMPEGMorph methodsFor: 'initialization' stamp: 'JMM 1/4/2001 11:02'!
initializeBlobShape

	| verts modifier |
	verts _ {59@40. 74@54. 79@74. 77@93. 57@97. 37@97. 22@83. 15@67. 22@50. 33@35. 47@33}.
	modifier _ 0 @ 0.
	(self quadNumber = 2) ifTrue: [ modifier _ 0 @ 75].
	(self quadNumber = 3) ifTrue: [ modifier _ 75 @ 0].
	(self quadNumber = 4) ifTrue: [ modifier _ 75 @ 75].
	verts _ verts + modifier.
	self 
		vertices: verts
		color: self color
		borderWidth: 1
		borderColor: Color black! !

!BlobMPEGMorph methodsFor: 'initialization' stamp: 'JMM 1/4/2001 10:54'!
initializeChildMpegPlayer: aMpegPlayerOrFileName  
	self initialize: false mpegPlayer: aMpegPlayerOrFileName ! !

!BlobMPEGMorph methodsFor: 'initialization' stamp: 'JMM 1/4/2001 10:54'!
initializePrimaryMpegPlayer: aMpegPlayerOrFileName  
	self initialize: true mpegPlayer: aMpegPlayerOrFileName  ! !

!BlobMPEGMorph methodsFor: 'stepping' stamp: 'JMM 10/19/2000 15:57'!
adjustColors
	^self! !

!BlobMPEGMorph methodsFor: 'stepping' stamp: 'JMM 12/19/2000 15:39'!
limitRange: verts
	" limit radius to range 20-120; limit interpoint angle to surrounding angles with max of twice of average separation. "
	| cent new prevn nextn prevDeg nextDeg thisDeg dincr |

	cent := self bounds center.
	new := Array new: verts size.
	dincr := 360 // verts size.
	verts doWithIndex: [ :pt :n |

		"Find prev/next points, allowing for wrapping around "
		prevn := n-1 < 1 ifTrue: [new size] ifFalse: [n-1].
		nextn := n+1 > new size ifTrue: [1] ifFalse: [n+1].

		"Get prev/this/next point's angles "
		prevDeg := ((verts at: prevn)-cent) degrees.
		thisDeg := ((verts at: n)-cent) degrees.
		nextDeg := ((verts at: nextn)-cent) degrees.

		"Adjust if this is where angles wrap from 0 to 360"
		(thisDeg - prevDeg) abs > 180 ifTrue: [ prevDeg := prevDeg - 360 ].
		(thisDeg - nextDeg) abs > 180 ifTrue: [ nextDeg := nextDeg + 360 ].

		"Put adjusted point into new collection"
		new at: n put: cent +
			(self selfPolarPointRadius: ((((pt - cent) r) min: 60) max: 20) "was min: 80"
				degrees: (((thisDeg min: nextDeg-5) max: prevDeg+5) min: dincr*2+prevDeg)) ].
	^ new
! !

!BlobMPEGMorph methodsFor: 'stepping' stamp: 'JMM 12/19/2000 15:29'!
mergeBlobs
	^self! !

!BlobMPEGMorph methodsFor: 'stepping' stamp: 'JMM 10/19/2000 16:29'!
stepTime
	^1.0 / (self mpegLogic videoFrameRate: self stream) * 1000! !

!BlobMPEGMorph methodsFor: 'drawing' stamp: 'JMM 1/4/2001 11:18'!
drawOn: aCanvas 
	"Display the receiver, a spline curve, approximated by straight line 
	segments. Fill with the MPEG movie"

	| cm f filled quadRect |

	cm _ Bitmap new: 2.
	cm at: 1 put: 0.
	cm at: 2 put: 32767.
	f _ Form extent: self extent depth: 16.
	filled _ self filledForm.
	(BitBlt toForm: f) sourceForm: filled;
		 sourceRect: filled boundingBox;
		
		destRect: (0 @ 0 extent: filled extent);
		 colorMap: cm;
		 combinationRule: Form over;
		 copyBits.
	quadNumber = 1
		ifTrue: [quadRect _ Rectangle origin: form boundingBox topLeft corner: form boundingBox center].
	quadNumber = 2
		ifTrue: [quadRect _ Rectangle origin: form boundingBox topCenter corner: form boundingBox rightCenter].
	quadNumber = 3
		ifTrue: [quadRect _ Rectangle origin: form boundingBox leftCenter corner: form boundingBox bottomCenter].
	quadNumber = 4
		ifTrue: [quadRect _ Rectangle origin: form boundingBox center corner: form boundingBox bottomRight].
	(BitBlt toForm: f) sourceForm: form;
		 sourceRect: quadRect;
		
		destRect: (0 @ 0 extent: f extent);
		 combinationRule: Form and;
		 copyBits.
	aCanvas image: f at: self position.
	self drawBorderOn: aCanvas.
	self drawArrowsOn: aCanvas! !

!BlobMPEGMorph methodsFor: 'drawing' stamp: 'JMM 1/4/2001 11:07'!
playStream: aStream
	mpegLogic playStream: aStream.
! !

!BlobMPEGMorph methodsFor: 'drawing' stamp: 'JMM 12/19/2000 16:41'!
playVideoStream: aStream
	mpegLogic playVideoStream: aStream.
! !


!BlobMPEGMorph class methodsFor: 'instance creation' stamp: 'JMM 1/4/2001 11:10'!
buildMorphics: aFileName
	| primary child |

	primary _ (self basicNew quadNumber: 1) initialize.
	self remember: primary.
	primary initializePrimaryMpegPlayer: aFileName.
	primary openInWorld.
	2 to: 4 do: [:i | 
		child _ (self basicNew quadNumber: i) initialize.
		self remember: child.
		child initializeChildMpegPlayer: primary.
		child openInWorld].
	^primary
! !

!BlobMPEGMorph class methodsFor: 'instance creation' stamp: 'JMM 1/4/2001 11:11'!
newWithMovie: aFileName
	| primary |

	primary _ self buildMorphics: aFileName.
	primary playStream: 0.
	^primary

! !

!BlobMPEGMorph class methodsFor: 'instance creation' stamp: 'JMM 1/4/2001 11:12'!
newWithMovieNoSound: aFileName
	| primary |

	primary _ self buildMorphics: aFileName.
	primary playVideoStream: 0.
	^primary

! !


!BlobMPEGMorph reorganize!
('access' form form: movieDrawArea mpegLogic mpegLogic: primary quadNumber quadNumber: stream)
('initialization' initialize:mpegPlayer: initializeBlobShape initializeChildMpegPlayer: initializePrimaryMpegPlayer:)
('stepping' adjustColors limitRange: mergeBlobs stepTime)
('drawing' drawOn: playStream: playVideoStream:)
!